proj varysail
`Demonstrates a technique for obtaining maximum VCG data using the
`weather criterion when the cargo wind plane varies with draft.
`
enter pm
create hull
ends 0, 100
top 10
bot 0
out 18
/

modify hull
margin 0      `Marking the deckedge for limit(1)
/

macro layer`Creating sail components
create cargo%1
class sail
ends 0, 100
bot %2
top %3
out .01
//
/
.layer 1 10 12
.layer 2 12 14
.layer 3 14 16
.layer 4 16 18
.layer 5 18 20
display
write
quit pm

lim (1) angle from equ to abs 14 or HF > 0
lim (2) abs ratio from abs 0 to abs 14 > 0.492
lim (3) angle from equ to ra0 > 15
wind (press) = 0.061
hmmt wind /cs

macro dr
variables d v
if "%2"="" then .start else type (cargo%2) = unset       `Unsetting existing sails for windage calcs
set d = %1
set v = {d} plus .5
heel = 0
trim = 0
draft = {d}
vcg = {v}
solve weight, lcg
solve maxvcg
if {verbose}=1 then .report1 else .report0   `verbose=0 produces short report - \\Draft   Maxvcg,  verbose=1, generates a full report, eg. hmmt report, status, ra/lim.
/


macro report1
hmmt report
status
ra /lim
/

macro report0
\ { d:2}  { FVCG:2}
/

macro start
if {verbose}=0 then exit
\\ Draft     Max VCG
/


variable verbose
set verbose=1
report
` Draft -Layer
.dr 6.5
.dr 6 5
.dr 5 4
.dr 4 3
.dr 3 2
.dr 2 1

print preview
report off