`Demonstrates using LS to get S-value tables. Required version 8.52B or later.

project svalues
read tanker.gf

report svalues
\\\\\\\\\\\
\S-Value Tables\
\\For Longitudinal Shear and Bending Calculations\
\\
\  S-Values are shear force and bending moments at specified longitudinal
\  positions due to bouyancy only.  They are related only to hull form
\  and have nothing to do with weight distribution.

UNITS MT

variables d,dd,d1,dloc,n
lbp 94.5
set dloc=47.25f `<--- mean draft location

`Create a frame file for this vessel:
me (report) tanker.fra
me ""FR65" -213
me ""FR55" -180
me ""FR45" -148
me ""FR35" -115
me ""FR25"  -82
me (report) off

`Declare variables to receive shear force and bending moment values for each frame:
  macro var
   variable fr%1$sf,fr%1$bm
  /

`iterate macro 6 times, incrementing first parameter by 10 each iteration.
.var(5,10) 25

`Macro to set short-named variables to shear force and bending moment values:
  macro fr
   variables sf%2,bm%2
   set sf%2={fr%1$sf}, bm%2={fr%1$bm}
  /

`Page heading macro:
  macro page
   page
   \S-Value Table\
   \
   \------------------- Trim %1 (M) ---------------------\
   \ Mean                                                      \
   \ Draft   Fr 25      Fr 35      Fr 45      Fr 55      Fr 65 \
   \ ----------------------------------------------------------\
  /

`Generates a table row:
 macro draft
  draft @ {dloc}={d}
  solve weight, lcg
  `status
  ls /fra /noprint /sternzero /noweight `/sternzero
  .fr 25 1
  .fr 35 2
  .fr 45 3
  .fr 55 4
  .fr 65 5
  \
  \{ d:2}{   sf1:0} {   sf2:0} {   sf3:0} {   sf4:0} {   sf5:0} S.F.\
  \      {   bm1:0} {   bm2:0} {   bm3:0} {   bm4:0} {   bm5:0} B.M.\
 /

`All drafts in range:
macro drafts
 .draft
 set d={d} plus {dd}
 if {d}>{d1} then exit
 set n={n} plus 1
 if {n}>15 then .page %1 | set n=0
 exit drafts %1
/

`At given trim:
macro trim
 trim %1/
 .page %1
 set d=2.0    `<--- initial draft
 set dd=0.25  `<--- draft increment
 set d1=8.25  `<--- final draft
 set n=0
 .drafts %1
/

vcg=5.0
heel=0
fix heel

.trim -1
.trim 0
.trim 1
.trim 2
.trim 3
print prev
report off