ENTER PM
UNITS MT
CREATE HULL
ENDS 17.5, -17.5
OUT 12.375
TOP 3.25
BOTTOM 0
/

WRITE BARGE.GF
QUIT



PROJ LAUNCH` - If project name match run file name, in GHS,
`      press F5 and Enter to launch run file.

ECHO Off

WATER fW
units MT

READ BARGE.GF

Title Launch at LiftOff
Report LIFTOFF-.pf`-output file name changed.

`ROLLER BAG LAUNCH SIMULATION USING GHS GROUND CONDITONS AND HYDROSTATICS

`````````````PRINCIPAL CHACTARISTICS``````````````````
WEIGHT 1600
LCG 0
TRIM -4.86
DEPTH -1.5

VARIABLE SLOPE = 4.86 `DEGREES
VARIABLES (LE) INIT_LOC LOC SPACE:1:4
VARIABLES (LE) K_SPRING=2 K_STEP ADV_BAG

SET SPACE=3.88  `SETS THE SPACING BETWEEN ROLLER BAGS
SET INIT_LOC = -13.58 `SETS THE LOCATION OF THE FIRST AIRBAG BEFORE ROLLING
SET LOC = {INIT_LOC}

`16 BAGS (8 PORT AND 8 STARBOARD) LAUNCHING PUTTING THE VARIABLES TO USE
` - Define a macro to create ground points
`Vessel trim matches ground slope. Ground points established with zero reaction.
`Vessel is 100% supported by ground because Depth is -1.
`Solve will let the vessel settle onto the blocks.
Macro MK-BAGS
GROUND "%1 Airbag P", *, {LOC}, -9, 0 /PEN: 0, {k_spring} /LINEAR
GROUND "%1 Airbag S", *, {LOC},  9, 0 /PEN: 0, {k_spring} /LINEAR
IF %1 < 8 THEN SET LOC = %1 TIMES {SPACE} PLUS {INIT_LOC}
/
.MK-BAGS (8,1) 1  `-Iterate macro 8x. Increment input parameter by +1.

Macro Report
GROUND REPORT
STATUS GROUND
DISP STATUS profile
/

.report
SOLVE
.report

Macro Roll `by sampling the loads at a spacing of 3.88 each ground pt
               ` can be deleted rather than shifted which makes for a
               ` simpler run file.
Delete "%1 Airbag P"
Delete "%1 Airbag S"
Depth *+{Depth_Inc}
Solve
If %1 < 8 then .report else ST | DISP STATUS profile
/

Variable Depth_Inc
Set Depth_Inc = 2 times {space} times sin {slope}
.Roll(8,1) 1

PRINT PREV
report off
quit