proj sailship

`Demonstrates a method to find the
` "Maximum Steady Heel Angle to Prevent Downflooding in Gusts"

MACRO MaxHeel
 VARIABLE T,TF0,TFL,TF,TMX,TSS,TSA
 VARIABLE GZF
 VARIABLE HA1,HA2
 `Find downflooding angle:
 SET TFL=60.0
 SET TMX=27.0
 RA 0 10 ... 90 /STOP:FLD /HOLD /NOTAB
 SET TF0 = {HEEL}
 SET TF = {TF0}
 IF {TF} > {TFL} THEN SET TF = {TFL}
 `Find RA at max allowed DF angle:
 HEEL = {TF}
 SOLVE TRIM
 SET GZF = {RAH}
 `Calculate HA1, zero degree heeling arm to produce this heel:
 SET T = COS {TF}
 SET T = {T} POWER 1.3
 SET HA1 = {GZF} DIV {T}
 `Calculate HA2, half of HA1:
 SET HA2 = {HA1} TIMES 0.5
 `Set up heeling moment function using HA2:
 SET T = {HA2} TIMES {WEIGHT}
 HMMT = {T} /C:1.3
 `Find heel under this HMMT:
 SOLVE
 SET TSS={HEEL}
 `Check whether exceeds allowed limit:
 SET TSA={TSS}
 IF {TSS}>{TMX} THEN SET TSA={TMX}
 HEEL 0
 `Report:
 \
 \Sailing Ship Maximum Allowed Steady Heel\
 \
 \Actual downdlooding angle:  { TF0:2}\
 \Maximum DF angle:           { TFL:2}\
 \Angle used for HA1:         {  TF:2}\
 \GZ at this angle:           { GZF:2}\
 \              HA1:          { HA1:2}\
 \           HA2(0):          { HA2:2}\
 \Steady heel:                { TSS:2}\
 \Maximum steady heel:        { TMX:2}\
 \Allowed steady heel:        { TSA:2}\
 \\
/

`Testing ...

`Read a GF:
read fv.gf

`Define downflooding point:
crtpt "Flood point" 0 10 13

`Set weight & CG:
depth 5
vcg 5
solve weight lcg

`Start report file:
report

`Execute the macro:
.MaxHeel

`Support with a righting arm curve:
RA

`View the result:
report /preview
report off