`Sample run for creating column-supported platform

enter pm

`First create some temporary shapes.  These are actually tanks but only their
`Shapes are of interest.  They will be deleted later.

create column.c
cylinder (32) 0,0,0, 0,0,50, 20 `<-- End points (L,T,V) and diameter.
/
create core.c
cylinder (16) 0,0,0, 0,0,50, 5
/
create bal.c
ends -10,10
top 15
fit column.c
fit (ext) core.c
/
create level1f.s
ends -10,0
top 25
bot 15
fit column.c
fit (ext) core.c
/
create level1a.s
ends 10,0
top 25
bot 15
fit column.c
fit (ext) core.c
/

`Now add plating thickness to the column so that it can be used for the legs.
modify column.c
shell 0.05,0.05,0
/

`Now create the actual "hull" made up of four legs, a deck and struts.
create hull
component leg1.c   `<-- This assigns a name to the Component we are creating.
shape column.c     `<-- This 'borrows' the Shape of column.c
vector -50,50,0    `<-- This locates the Shape to suit this Component.
component leg2.c
shape column.c
vector -50,-50,0
component leg3.c
shape column.c
vector 50,50,0
component leg4.c
shape column.c
vector 50,-50,0
component deck.c
ends -70, 70
top 65
bot 50
out 70
component strutf.s
cylinder -50,0,60, -50,55,25, 7
fit deck.c
fit leg1.c
component strutf.p
shape strutf.s
/

`Make a pattern (macro) for creating the compartments in the legs.
`%1 is the leg number; %2 and %3 are the long. & trans. shifts.
MACRO legtks
create core%1.c
shape core.c
vector %2,%3,0
//
create bal%1.c
shape bal.c
vector %2,%3,0
//
create level1f%1.s
shape level1f.s
vector %2,%3,0
//
create level1f%1.p
shape level1f.s
vector %2,%3,0
//
create level1a%1.s
shape level1a.s
vector %2,%3,0
//
create level1a%1.p
shape level1a.s
vector %2,%3,0
//
/  `<-- end of macro

.legtks 1 -50,50
.legtks 2 -50,-50
.legtks 3 50,50
.legtks 4 50,-50

`Make some tanks in the deck.
create fuel1.s
contents fo
ends 0, 20
inb 60
fit hull\deck.c
/
create fuel1.p
opp fuel1.s
/

`Delete the macro and the temporary tanks.
macro legtks
/
delete column.c
delete core.c
delete bal.c
delete level1f.s
delete level1a.s


`Write the Geometry File.
write tlp.gf

`Back to the main program.
quit