project MINGM
`Demonstrates a means of getting minimum GM tables.

read tanker
lbp=94.5

report mingm

`Report title page:
\\\\\\\\\\\Curves of Max VCG and Min GM\

`Stability criterion:
LIMIT AREA FROM 0 TO 30 > 0.055
LIMIT AREA FROM 0 TO 40 OR FLD > 0.090
`LIMIT AREA FROM 30 TO 40 OR FLD > 0.030
LIMIT RA AT 30 > 0.200
LIMIT ANGLE FROM 0 TO MAX > 25
LIMIT GM UPRIGHT > 0.150

variable(len) draft1, draft2, draftN, draftInc
variable nDraft
variable(len) trim1, trimInc
variable nTrim
variable(len) lbp

`Draft and trim range settings:
set draft1=3.0
set draftN=8.0
set draftInc=1.0
set trim1=-2.0
set trimInc=2.0
set nTrim=3
set lbp=94.5


set draft2={draft1} plus {draftInc}
set nDraft={draftN} minus {draft1} div {draftInc} plus 1

macro mxmn
 trim=%1/
 page
 vcg=0
 maxvcg {draft1} {draft2} ... {draftN}
 page
 \Maximum VCG and Minimum GM as a function of Draft\
 \   Draft      Trim      Displ   Max VCG   Min GM \
 .mingm ({nDraft},{draftInc}) {draft1}
 \Negative trim is forward.  Units: {LUNIT} and {WUNIT}\
/

macro mingm
 draft=%1
 solve weight, lcg
 vcg=0
 vcg=max
 if {vcg}=0 then exit
 variable d=%1
 variable t
 set t=tan {trim} times {lbp}
 \ {  d:2} {    t:2}{ weight:1} {  vcg:2} { gmt:2} \
/

.mxmn ({nTrim},{trimInc}) {trim1}

print /preview
report off