`Example run file for finding intact limiting drafts to avoid deck immersion
`when damaged.

project limdraft

`Must have deck edge marked in model:
if not fexist tanker.gf then read tanker.gf | mc tanker.gf fixup /deckedge | clear
read tanker.gf

`Must designate lbp:
lbp = 0, 95f

report

variable n,f,q,t,apd

macro err1
 \\*** Heel too large: {heel} degrees ***\
/
macro err2
 \\*** Unable to find a solution for the AP draft of {apd} ***\
/
macro loop
`This macro finds the trim at given AP draft for zero freeboard when
`flooded (if possible).
 type intact
 heel = 0
 trim = {t}
 draft @ AP = {apd}
 solve weight, lcg
 type flood
 set error = -1
 solve
 if {error}>=0 then .err2 | exit
 set error = 0
 set q = ABS {heel}
 if {q} > 20 then .err1 | exit
 set f = ABS {freebd}
 if {f}<0.01 then exit
 if {f} > 10 then set f = 10
 set q = {ap} minus {fp}
 set f = {f} div {q}
 set f = atn {f}
 set n = {n} plus 1
 set q = {n} div 10 plus 1
 set f = {f} times {q}
 if {freebd} > 0 then set t = {t} minus {f} | exit loop
 if {trim}>0 then set t = {t} minus {f} | exit loop
 set t = {t} plus {f}
 exit loop
/


macro lim
`This macro finds the limiting FP draft and reports the flooded status
`resulting from the intact AP & FP drafts (which are also reported).
set n = 0
set t = 0
set apd = %1
vcg = %2
.loop
status weight, displ, freebd /noref
type intact
solve
draft @ AP /print /title:" Intact limiting draft at AP"
draft @ FP /print /title:" Intact limiting draft at FP"
\\
/

macro limdr
`This procedure runs through a series of AP drafts, finding limiting FP draft
`for each.  The VCG for each intact draft is also given.  The tanks to be
`flooded are assumed to have been designated by way of the current default
`tank selection.
type (*) intact
`   AP draft   VCG
.lim   4.0     4.00
.lim   5.0     4.25
.lim   6.0     4.50
.lim   7.0     4.75
.lim   8.0     4.75
.lim   8.5     4.75
/

tanks = cgs3.s,cgc3.c,wbdb2.s
.limdr
tanks = cgs6.s,wbdb4.s
.limdr
tanks = cgs4.s,cgc4.c,wbdb3.s
.limdr

view