`Based on ISO power yacht stability standards
`Design category "A" assumed

MACRO ISOY-FLD
 PAGE
 \\----\
 \ISO POWER YACHT - DOWNFLOODING (6.1)\
 \Downflood Height (6.1.2)\
 \Downflooding Angle (6.1.3)\
 \----\
 \\\\>>>> Heel induced by passenger crowding <<<<\
 \\
 CRTPT OFF
 CRTPT (1) "%1" %2 %3 %4
 HEEL = 0
 SOLVE
 STATUS WEIGHT, CRTPT /NOREF

 Part = hull
 Refpt = %2, %3, %4     `<--- Downflooding point
 VARIABLE h
 SET h = {Lh} DIV 17

 \
 \(6.1.2) Downflood height above waterplane = {height}\
 \This height must be > {h:2} (hull length/17.0)\
 mac pass
  \PASSES\
 //
 mac fail
  \FAILS!\
 //
 IF {height}>{h} THEN .pass ELSE .fail

 LIM OFF
 LIM TITLE DOWNFLOODING ANGLE (6.1.3)
 LIM ANGLE FROM EQU TO FLD > 25
 LIM ABS ANGLE AT FLD > 30

 VARIABLE t
 SET t = 24 MINUS {Lh}
 SET t = {t} TIMES {t} TIMES {t}
 SET t = {t} DIV 600
 SET t = {t} PLUS 10
 LIM ANGLE AT EQU < {t}
 \\\Max heel angle at equilibrium = 10 + (24 - {Lh})^3 / 600 = {t:2}\
 PAGE
 RA 0 5 /LIM:ATT /GRAPH:NONE
/


MACRO ISOY-WW
 PAGE
 \\----\
 \ISO POWER YACHT RESISTANCE TO WAVES & WIND (6.3)\
 \Rolling in Beam Waves & Wind (6.3.1)\
 \----\
 \\\\>>>> Heel induced by wind <<<<\
 \Heeling moment = {HMMT}\
 \\
 HEEL = 0
 SOLVE
 HMMT REPORT
 \
 STATUS WEIGHT /NOREF

 VARIABLE x
 SET x = 10 DIV {DISPL} PLUS 24
 \\\\\Roll angle = 24 + 10 / {DISPL} = {x:2}\
 ROLL = {x}
 HEEL = *-ROLL
 LIM OFF
 LIM TITLE ROLLING IN WAVES & WIND (6.3.1)
 LIM RATIO FROM ROLL TO ABS 50 OR FLD > 1
 PAGE
 RA 0 5 /LIM:ATT
/

MACRO ISOY-W
 PAGE
 \\----\
 \ISO POWER YACHT RESISTANCE TO WAVES & WIND (6.3)\
 \Resistance to Waves (6.3.2)\
 \----\
 \\\\
 HEEL = 0
 SOLVE
 STATUS WEIGHT /NOREF

 MACRO B
  LIM RA AT MAX TO ABS 30 > 0.2
  \\Area requirement is 0.2 m-rad.\
 //
 MACRO C
  VARIABLE x
  SET x = 30 MINUS {HEEL} TIMES 0.057 PLUS 3.15
  LIM AREA: DEGREES
  LIM AREA FROM ABS 0 TO MAX > {x}
  \\Area requirement = 3.15 + ( 30 - {HEEL} ) x 0.057 = {x} m-rad.\
 //
 LIM OFF
 LIM TITLE RESISTANCE TO WAVES (6.3.2)
 LIM ABS ANGLE AT MAX > 15
 RA 0 5 ... 120 /STOP:MAX /HOLD /NOPRINT
 \\\\Angle of maximum righting arm = {HEEL:2} degrees.\
 IF {HEEL} < 30 THEN .C ELSE .B
 HEEL = 0
 SOLVE
 PAGE
 RA 0 5 /LIM:ATT
/

macro sample
read my.gf
units mt           `<--- Metric units required

variable Lh
set Lh = 29.6      `<---- Put length of hull here

weight = 145.0     `<------ full load weight w/o passengers
lcg = 14.339       `<------ full load lcg w/o passengers
vcg = 1.804        `<------ full load vcg w/o passengers

ADD "28 People up dk"   2.100, 10.67, 2.92, 5.953 `<--- Offset loading
ADD "57 People mn dk"   4.275, 15.13, 2.74, 3.591 `<--- Offset loading

.ISOY-FLD "Engine vent" 17.09, 1.52, 3.75        `<--- Downflooding point

ADD "28 People up dk"  *, *, 0.0, * /nowarn `<--- Normal loading
ADD "57 People mn dk"  *, *, 0.0, * /nowarn `<--- Normal loading

HMMT =  17.017  `<--- Wind heeling moment
.ISOY-WW
HMMT OFF

.ISOY-W
/
`.sample