`Demonstrates crane stability - after DNV rules

project CRANEDNV

enter pm
title crane barge
units m
create hull
 ends -50 50
 bot 0
 top 10
 out 14
 margin 0
/
create crane
 class sail
 cyl -15 0 10  -15 0 17  20
comp boom
 top 18 @ -10, 46 @ 40
 bot 15 @ -10, 43 @ 40
 out 1
/
write
quit pm

crtpt "fld pt" 0, 12, 12 /symm
draft 4
vcg 9
solve weight, lcg

macro hookload
 ADD "Hookload" 700, 0, 30, 43
/

report /box:bw
me repfont

\DNV D 200 - Accidental load drop - Earlier (Heeling moment) Version\
\---\
\
  .hookload
  ADD "Counterwt" 3000, 0, -5, 12
  SOLVE
  \Before load drop\
  \---\
  status
  DELETE WEIGHT "Hookload"
  SOLVE TRIM
  \\Immediately After load drop\
  \---\
  status
  VARIABLE h = {HEEL}
  HEEL = 0
  SOLVE TRIM
  \\At zero heel before conversion to heeling moment\
  \---\
  status
  VARIABLE hm,tc
  SET tc = {TCG}
  SET hm = {tc} times {WEIGHT}
  SOLVE TCG
  HMMT = {hm}
  SET h = minus {h}
  HEEL = {h}
  ANGLES *
  SET h = minus {h}
  HEEL = {h}
  LIMIT(1) RESIDUAL RATIO FROM 0 TO FLD OR RA0 > 1.4
  LIMIT(2) ANGLE AT EQU < 15
  RA /LIM:ATT
  TCG = {tc} `Restore TCG from the above
  HMMT OFF

subtitle DNV D 200 - Accidental load drop - Direct Weight Loss Method \
page

  .hookload
  SOLVE
  \Before load drop\
  \---\
  status
  DELETE WEIGHT "Hookload"
  SOLVE TRIM
  \\Immediately After load drop\
  \---\
  status
  LIMITS OFF
  LIMIT(1) RESIDUAL RATIO FROM 0 TO FLD OR RA0 > 1.4
  LIMIT(2) ANGLE AT EQU < 15
  IF {HEEL}>0 THEN ANGLES 0 -2.5 ELSE ANGLES 0 2.5
  page
  RA /LIM:ATT


subtitle DNV D 300 - Alternative Intact Stability during Heavy Lift\
page

  .hookload
  SOLVE
  \Before wind\
  \---\
  status
  ANGLES *
  `WIND 90
  `HMMT WIND /CONST
  HMMT 12000 `For demo
  HMMT *
  LIMITS OFF
  LIMIT(1) ABS RATIO FROM 0 TO FLD OR RA0 > 1.4 `rev 4/11
  LIMIT(2) ANGLE FROM EQU TO DI > 0
  page
  \RA curve with wind\
  \---\
  RA /LIM:ATT
  HMMT OFF
  LIMITS OFF
  LIMIT(1) AREA FROM EQU TO FLD OR ABS 20 > 0.03
  page
  \Absolute RA curve without wind\
  \---\
  RA /LIM:ATT

print /preview
report off
end