`Start of Custom Load Status Table Runfile.
`
READ TANKER.GF
DRAFT 3
TRIM 0 | HEEL 0
SOLVE WE,LCG,TCG
DI(*)STATUS /SYNC

LBP = 95.129

LOAD  (CGC1.C).75
LOAD  (CGC*) .90
LOAD (DODBER*) .95
LOAD (DODAY*) .95
LOAD (DIRTYO.S) .95
LOAD (DRAIN.P) .95
LOAD (FODT*) .95
LOAD (FOER*) .95
LOAD (FOSET*) .95
LOAD (FODAY*) .95
LOAD (FW*) .95
LOAD (LOSYS.C) .95
LOAD (LOSTO.S) .95
LOAD (WBDB4*) .95
SOLVE

VARI N,BBLS,TVL,TWT,TFS,PNME
VARI (STRING) TNAME
VARI MCON = 6.28981077

MACRO TSTAT          `Macro to create each Load Status line in the table
TANK {PNME}
IF {TNVOLUME} < .01 THEN EXIT
SET TVL =  {TNVOLUME}
SET TWT = {TWEIGHT}
SET TFS = {TFSMMT}
SET BBLS = {TVOLUME} TIMES {MCON}   `ONLY FOR CUBIC METER CONVERSION
`\ TANK NAME     SPGR     LOAD%    VOLUME (M3)    WEIGHT    BARRELS      FSM
\{PNME    }{   SPGR:3}{ LOAD:2}{      TVL:2}{      TWT:2}{   BBLS:2}{   TFS:2}
/

MACRO GETTANK         `Macro to retrieve single tank name from list of tanks in GF
set i={i} plus 1
set PNME=item {i} "{tklist}"
IF "{PNME}"="" THEN EXIT
.TSTAT
EXIT GETTANK
/

VARI DIST
SET DIST = 95.129 TIMES TAN {TRIM}

REPORT TANKSTATUS.PF /BOX:COLOR
MESSAGE REPSTART /BOX`:bw
\STATUS OF LOADING\
\TRIM: {DIST:2} / 95.129    HEEL: {HEEL:2}\
\  TANK NAME     SPGR     LOAD%    VOLUME (M3)    WEIGHT    BARRELS      FSM
tanks * /in:-999                              `Select all tanks in GF
variable tklist="{PNAME}"             `Copy tank list from PNAME system variable to a user-defined variable
variable i=0
.GETTANK
tank off
ME REPFOOTER
\---                                                                                                         Units {WUNIT}
ME REPEND
REPORT CLOSE /PREVIEW
`QUIT