`Demonstrates crane hookload drop with reference to BV criterion

proj bvdrop
units mt

enter pm
create hull
 ends -25, 25
 out 10
 top 10
 bot 0
/
write {project}.gf
quit pm

crtpt "Flood point" 0, 6, 16 /symm

draft 5
vcg 5
solve weight, lcg

report

`Boom on port side:
boom "Suspended Wt" 175, 0, 0, 10,  50, -90, 45
boom "Crane Boom"    60, 0, 0, 10,  25, -90, 45

hmmt 4000 /c1 `counter ballasting
solve

\Crane in operation with load in place\
status
\Heeling moment representing counter ballast\
hmmt report

variable t1,tc,t3,r
set t1={HEEL}

\\Angle Theta1 = {t1:2}\
\

delete weight "Suspended Wt"
solve
\After hook load drop\
status

set tc={HEEL}
set r={tc} minus {t1}

\\Angle ThetaC = {tc:2}\

angles 0 5

macro findt3
 lim off
 lim res ratio from abs {t1} to abs {t3} = 1
 ra /lim /noprint
 `\ t3={t3}  LIMMARG={LIMMARG}
 set t3 = minus {LIMMARG} div 100 plus {t3}
 `\ new t3={t3}
 if {t3}<{tc} then set t3={tc} plus 1
 if {t3}>30 then set t3=30
/
set t3={tc} plus {r}
.findt3 (20)

\\Angle Theta3 = {t3:2}\

lim off
lim res ratio from abs {t1} to abs 30 or fld > 1
lim angle from {t3} to ra0 or fld > 20

page
RA /lim:att /graph:clean


print preview
report off
end