GHS BULLETIN

GHS BULLETIN Water on Deck

GHS provides two special tank types for the purpose of modeling the effects of the extra burden of water on deck due to waves.

The first, FLOODED PLUS, is an extension of the FLOODED type. It raises the flooded waterplane above the external waterplane by an amount such that the increased volume is equal to the volume indicated by the LOAD setting.

The other type is called DECK. It is similar to the DAMAGED type with LOAD = 0 and an additional head of water added to that of the external waterplane. The parameter /HW: must be included with the TYPE command in order to specify the value of the additional head.

Following is a run which demonstrates the use of these types to model the two methods of treating water on deck.

 macro makeship

  clear
  enter pm
  create hull
   ends 0 100
   top 20
   bot 0
   out 10
  //
  create deck.c
   ends 15 85
   bot 8
   fit hull
  //
  display
  write
  quit pm
 /
 macro interp  `%1=x, %2=x1, %3=y1, %4=x2, %5=y2, %6=result var name
  if %1<%2 then set %6 = %3 | exit
  if %1>%4 then set %6 = %5 | exit
  variable t
  set t = %4 minus %1 times %3
  set %6 = %1 minus %2 times %5 plus {t}
  set t = %4 minus %2
  set %6 = {%6} div {t}
 /
 macro wod
  type = flood
  solve
  variable hw,f,v
  variable (string) u
  set u = "{wunit}"
  unit mt
  .interp {HEIGHT}, .3, .5, 2, 0, "hw"
  .interp {hs}, 1.5, 0, 4, 1, "f"
  set hw = {hw} times {f}
  if %1="NEU" then type = deck /hw:{hw}
  mac t
   type = intact
   heel = 0 | trim = 0
   load = .5
   solve depth
   set f = {HEIGHT}
   set v = {TVOLUME}
   set f = {f} minus 0.1
   load = height:{f}
   solve depth
   set v = {TVOLUME} minus {v} times 10
   \\Deck area is {v} sq. meters\
   set v = {v} times {hw}
   contents = fw
   load = weight:{v}
   type = flood plus
  //
  if %1="POE" then .t
  unit {u}
  solve
 /
 macro stat
  \With water on deck, wave height: {hs} meters  hw: {hw} meters\
  status
  /
 macro ra
  heel = 0
  ra /area /nowarn
 /

 `===== Start of project commands  ======
 `Get geometry
 project testwod
 if fexist {project}.gf then read else .makeship
 report /nograph

 `Set ship weight and C.G.
 draft = 4.5
 vcg = 5
 solve weight, lcg

 `Set point of damage
 variable pod
 set pod = "50a, 10s, 8"  `Point of damage, also used to determine freeboard.
 refpt (hull) = {pod}

 `Select deck to be flooded
 tank deck.c
 refpt = {pod}
 type = flood

 `Induce heeling moment
 tcg = 0.5

 \\==== Initial condition without water on deck: ====\
 solve
 status

 `Set wave height
 variable hs
 set hs = 2.75 `Wave height in meters

 macro case
  page
  \\%2 method\
  .wod %1
  .stat
  .ra
 /

 .case neu "Northern European"
 .case poe "Panel-of-Experts"

 view

If you would like to see another bulletin created regarding a specific topic, please email Creative Systems, Inc. at support@ghsport.com.