The following run file demonstrates how 46 CFR 28.565 can be applied using
GHS.


proj uscgwod

read fv.gf

enter pm

create bulwark.c    `Create a tank to model the volume between bulwarks
ends -23.10, 35.0
top 17.0
bot 13.0
out 11.0
fit (external) hull.c
/
display
write fvb.gf
quit pm

draft 8.0
vcg 11.0
solve weight, lcg

crtpt (1) "Downflooding Opening" -23.1, 11.6, 17.0 /sym
crtpt (2) "Tank Bulwark Sym" 0, -11.0, 17.0 /noflood /tank:bulwark.c /sym

tank bulwark.c
ref 0, 11.0, 17.0
load 1.0
type spilling
`type damaged  `<--- use damaged to truncate the HMMT TANK curve when the bulwark is immersed.

angle 0 2.5 ... 90
hmmt tank   `<--- derives an hmmt curve from bulwark.c

load 0  `<--- the hmmt will be used in lieu of the tank model
type intact  `<--- the tank is not part of the hull so shouldn't remain as damaged type.

limit(1) residual ratio from abs 0 to abs 40 or ra0 > 1
limit(2) residual ratio from abs 0 to fld or ra0 > 1

report
hmmt report
page 97%
fix trim
ra /lim:attained
angles 0 -2.5 ... -90
ra /lim:attained
report off
end