GHS Port Reference Center
Information for maritime designers, engineers and builders
Maintained by Creative Systems, Inc., Creators of GHS
Click here for information about GHS and other fine marine software.
Go to Main page

Demonstrates how the permeability of any component can be changed in order to get more accurate wind plane representation when it is shielded by another component.
    `Demonstrates how the permeability of any component can be changed in order
    `to get more accurate wind plane representation when it is shielded by
    `another component.
    `
    `The steps are as follows.
    ` 1. Set up a condition and capture the draft and trim in user variables.
    ` 2. Use Part Maker to modify the permeability of one or more components
    `    and/or delete parts or components.
    ` 3. With the modified geometry, set the trim and draft then capture the
    `    heeling moment in a user variable.
    ` 4. Reread the original geometry file.
    ` 5. Reestablish the condition.
    ` 6. Reset the heeling moment from the user variable.
    ` 7. Run the stability calculation.
    
    project windmod
    page 1
    
    `Create a test vessel
    enter pm
    create hull
    ends 0 100
    top 10
    bot 0
    out 10
    comp stack.s
    ends 70 80
    top 20
    bot 10
    in 8
    out 10
    comp stack.p
    ends 70 80
    top 20
    bot 10
    in 8
    out 10
    /
    create sponsons
    class hull
    ends 20 80
    top 10
    bot 3
    out 11
    in 10
    /
    write windmod.gf
    quit pm
    
    display
    
    macro windmod
    enter pm
    modify stack.p
    perm 0.25
    //
    delete sponsons
    write temp.gf
    qu pm
    /
    
    macro liteship
    type (*) intact
    load (*) 0
    heel 0 | trim 0 | depth 5
    vcg 5
    solve weight lcg
    /
    
    report
    page keep on
    \\\\\\\Demonstration\
    \\\Deriving Heeling Moment\
    \\with\
    \\Wind Plane Corrections\
    \\\\
    
    macro cond `pass the particular condition macro name as a parameter
    report off
    .%1
    heel 0
    solve trim
    variable t,d
    set t = {trim}
    set d = {depth}
    .windmod 0.25
    .%1
    heel 0
    trim {t}
    depth {d}
    hmmt wind /const
    report /a
    hmmt report
    report off
    set t={hmmt}
    read windmod.gf
    .%1
    hmmt {t}
    report /a
    .calc
    /
    
    macro a
    .liteship
    wind 50
    add "Weight A" 20 50 0 5
    /
    
    macro b
    .liteship
    wind 100
    add "Weight B" 40 50 0 5
    /
    
    macro calc
    solve
    status
    ra 0
    /
    
    .cond a
    .cond b
    
    view
    report off
    
    

Add a free link to your site
Copyright © , Creative Systems, Inc.