`Example run file illustrating how to calculate tank loads to shift for desired vessel trim

proj trim

read barge.gf

content (*) fo
load(*) .6

vcg 6
we 600
lcg 150
tcg 0

so
report
\Initial Condition to calculate trimming moment\
\freeboard: {freebd}
\
variable t
set t = {freebd} times 2
trim {t}/300
so dr
st
di(*) status
\Equilibrium Condition - All tanks loaded 60%\
\freeboard: {freebd}
\Righting Arm in Trim: {RAT}
vari lcg1, lcg3
tank 1.s 1.p
set lcg1 = {tlcg}
tank 3.s 3.p
set lcg3 = {tlcg}
\Center of 1: {LCG1}
\Center of 3: {LCG3}
vari arm wt2move curwt
set arm = {lcg3} minus {lcg1}
set wt2move = {displ} times {rat} div {arm}
\Arm: {arm}
\Weight to move: {wt2move}
\Weight to move = Displ X Rat / Arm
\ {wt2move} = {displ} X {rat} / {arm}
tank 1.s
set curwt = {tweight}
\weight of each tank: {curwt}
\
so
st
di(*) status
set wt2move = {wt2move} div 2
vari wt1, wt3
set wt1 = {curwt} minus {wt2move}
set wt3 = {curwt} plus {wt2move}
\Calculating Weight to shift Aft to arrive at desired Trimmed Condition\
\weight for forward tanks:{wt1}
\weight for aft tanks:{wt3}
\
\*** Reducing load in tank1.p & .s to {wt1} ***\
\*** Increasing load in tank3.p & .s to {wt3} ***\
\
load (1*) we:{wt1}
load (3*) we:{wt3}
so
st
di(*) status

print prev
report off