`Progressive flooding simulation using the LOAD FLOW and CRTPT commands
`Download the sample report: PROG.zip
`Download BARGE.GF which is used in this run file: BARGE1.zip

clear | clear all

proj prog
read barge.gf
cont(*) "Flooding" 1.025
dr 4
vcg 5
so we lcg
load (*) 0
cls

macro fld `%1: time increment for flow in minutes
 di(*) status plan, body @50 @40 @30 /yesempty /fra
 load(*) flowc: %1 minutes
 so
 st we`:brief
 wait 0.25
/

macro deltaHt
 refpt(hull) 40 5 2
 refpt(t2.s, t3.s) 40 5 2
 \{15}Checking the distance to the three relevant waterplanes
 \{15}to see if the full equilibrium has been reached.
 part hull
 \Crtpt2 is {height} above the external waterline.
 part t2.s
 \Crtpt2 is {height} above the internal waterline in {pname}.
 part t3.s
 \Crtpt2 is {height} above the internal waterline in {pname}.
 \{15}If not close enough, reduce the time step and flow again.
/

report
di(*) status plan, body @50 @40 @30 /yesempty /fra /sync
\{11}This run file demonstrates progressive flooding using LOAD FLOWC.
\{11}Critical points are used to model openings which permit flow.
\{11}Initial head pressures across each opening determine flow rates,
\{11} which are constant for the specified time interval.
crtpt "Hole in T3.S"      50 10 0 /tank:T3.s /open:0.4
crtpt "From T3.S to T2.S" 40  5 2 /tank:T2.s /open:0.4 /inside:T3.s
st crtpt
\\{11}Next we will allow flow for 25, 1-minute long, time steps.
\{11}Note: The body view at Bulkhead2 shows the level in Tank 3.
wait
.fld(25) 1
\{11}Did you see Tank 3 fill up to CRTPT 2 before Tank 2 started to fill?
.deltaHt
wait
.fld(5) .5
.deltaHt
wait
.fld(5) .25
.deltaHt
\{11}The two tanks have filled to match the external waterplane.
ME "The report which will open momentarily documents each time step.
wait
print preview
report off