GHS Port Reference Center
Information for maritime designers, engineers and builders
Maintained by Creative Systems, Inc., Creators of GHS
Click here for information about GHS and other fine marine software.
Go to Main page

Combining Heeling Moments of Varying Shapes.
    CLEAR
    PROJ HM_Add1
    READ TANKER.GF
    LBP 0 94.0F
    WEIGHT 3000 -45 0 5
    LOAD (CGC*) .95
    
    
    VARIABLE X, Y, Z, T, H
    VARIABLE(str) HMstring
    
    macro hmmtrep `%1: heel angle
                  `call using the form .hmmtrep (n,i) s for a report of heeling moments
                  ` at n angles and increments of i starting from angle s
     set H=%1
     heel %1
     \HMMT @{ H} degrees heel ={ HMMT:2}\
     heel 0
    /
    
    MACRO Q2_MOD `%1: heel angle; %2: ""|noprint
     HMMT OFF
     heel %1
     solve dr
     HMMT TURN 400, 15 /C1
     SET X = {HMMT}
     WIND 40
     HMMT WIND /C2 /BAND:1 /TRIMALLOW
     SET Y = {HMMT}
     HMMT TANK
     SET Z = {HMMT}
     if %2<>NOPRINT then \HMMT Report\
     if %2<>NOPRINT then  \Heel={heel}; Trim={trim}; Draft={drvalu}\
     if %2<>NOPRINT then \HMMT from Turn={X:2}, from Wind={Y:2}, from Tank={Z:2}\
     set T={X} plus {y} plus {Z}
     if %2<>NOPRINT then \Total HMMT={T:2}\
     HMMT {T} /C1
    /
    
    macro sum_HMMT `%1: heel angle
                   `creates user defined HM by summing Tank,Turn & Wind HMMTs
     set H=%1
     .Q2_MOD %1 noprint
    `\ Angle----Turn----Wind----Tank---Total\
     \{ H:0} {  X:1} {  Y:1} {  Z:1} {  T:1}\
     set HMstring="{HMstring} {T}@%1"
     HMMT={HMstring}
    /
    
    MACRO Q3_Mod
     HMMT OFF
     SOLVE
     ANGLES *
     \SUMMATION OF HMMT FROM TURN, WIND, AND TANK\
     \ Angle----Turn----Wind----Tank---Total\
     .sum_HMMT(10,10) 0
     \\
     HMMT *                        `assumes tank heeling moments are symetrical
     HMMT REPORT
     PAGE
     SOLVE
     Heel 0
     TANK (*) FROZEN              `free surface effects are already captured by HMMT TANK
     RA /LIM:ATTAINED /STOP:RA
     HMMT OFF
    /
    
    
    LIMITS OFF
    LIMIT TITLE BV-1030-1 GROUP A, STILL WATER, WIND 40 KNOTS + TURNING CIRCLE
    LIMIT (1) ABSOLUTE ANGLE AT EQUIL < 15
    LIMIT (2) RA at 35 > 0.1
    
    REPORT /BOX:COLOR
    
    SOLVE
    STATUS WE DI GHS /FSM
    DI(*) STATUS PROFILE:OUTBOARD, PLAN
    PAGE
    ANGLES 0,10,...,90 `set angle values
    HMMT TURN 400, 15 /C1
    HMMT REPORT
    \HEELING MOMENT FROM TURNING\
    .hmmtrep(7,10) 0  `print heeling moments for angles 0 10 ... 60
    \
    WIND 40
    HMMT WIND /C2 /BAND:1 /TRIMALLOW
    HMMT REPORT
    \HEELING MOMENT FROM WIND\
    .hmmtrep(7,10) 0  `print heeling moments for angles 0 10 ... 60
    \
    HMMT TANK
    HMMT REPORT
    PAGE
    .Q3_Mod
    
    REPORT PREVIEW
    REPORT OFF
    
    
    

Add a free link to your site
Copyright © , Creative Systems, Inc.