proj CRANEDNV

`A crane barge energy calculation simulating the sudden loss of a hook load
`DNV Rules for Ships, July 2007 Pt.5 Ch.7 D200

`Create a simple rectangular barge hull:
enter pm
create hull
ends 0 100
top 6
bot 0
out 30
/
write
quit pm

variable theta0, thetaL

report

`Lightship weight & CG:
draft 4
vcg 12
solve weight, lcg

set theta0={heel}

`Define floodpoint
crtpt "vent" 50 -25 15 /fld /symm


`Add counterbalance and hook loads:
boom "counter" 100 50 0 15 20 90 0
boom "load" 50 50 0 11 80 -90 10

`Initial status: heel angle with hook load
solve
set thetaL = {heel}
\\\===== Before hook load is dropped =====\
status


`Delete hook load:
delete "load"

solve trim ``Do not solve for heel here
\\\===== After hook load is dropped and before heel changes =====\
status

``Convert counter balance to heeling moment:
heel {theta0} `Neutral heel
hmmt off
solve trim
variable x={rah}
set x=minus {x} times {weight}
solve trim, tcg
hmmt {x} /c1
heel {thetaL} `Back to angle at load drop

page
\\\
\ Note: The following righting arm curve represents heeling back
\ after load drop where the counter weight is represented as a
\ heeling moment.

lim res ratio from 0 to fld > 1.4
angle 0 1
if {hmmt}<0 then angle 0 -1
ra /lim:att /graph:clean

`--------------------------------------

`A simpler and more realistic method uses the TCG shift directly
`instead of converting it to a heeling-arm curve:

page
\\\
\ Note: The following righting arm curve represents heeling back
\ after load drop where the counter weight is represented directly
\ in its TCG.

hmmt off
delete "counter"
tcg 0
boom "counter" 100 50 0 15 20 90 0
boom "load" 50 50 0 11 80 -90 10
solve
angle 0 1
if {heel}>0 then angle 0 -1
delete "load"
ra /lim:att /graph:clean


report preview

report off

end