`Demonstrates crane hookload drop with reference to BV criterion
`Revised 6/14/10

proj bvdrop
units mt

enter pm
create hull
ends -25, 25
out 10
top 8
bot 0
/
write {project}.gf
quit pm

crtpt "Flood point" 0, 8, 14 /symm

draft 5
vcg 5
solve weight, lcg

report

macro boom
`Boom azimuth angle: %1
boom "Suspended Wt" 150, 0, 0, 10, 50, %1, 45
boom "Crane Boom" 60, 0, 0, 10, 25, %1, 45
if %1<0 then hmmt 4000 /c1 else hmmt -4000 /c1 `counter ballasting
/

`.boom -90
.boom 90

solve

\Crane in operation with load in place\
status weight, displ, crt /noref
\Heeling moment representing counter ballast\
hmmt report

variable t1,tc,t3,r
set t1={HEEL}

\\Angle Theta1 = {t1:2}\
\

delete weight "Suspended Wt"
solve
\Equilibrium after hook load drop\
status weight, displ, crt /noref

set tc={HEEL}
set r={tc} minus {t1}
set r=abs {r}

\\Angle ThetaC = {tc:2}\

angles 0 2
if {t1}>0 then angles 0 -2

heel {t1}

macro findt3
lim off
lim res ratio from roll to abs {t3} = 1
ra /lim /noprint
`\ t3={t3} LIMMARG={LIMMARG}
set t3 = minus {LIMMARG} div 30 plus {t3}
`\ new t3={t3}
if {t3}<{tca} then set t3={tca} plus 1
if {t3}>30 then set t3=30
/
variable tca
set tca=abs {tc}
set t3={tca} plus {r}
.findt3 (20)

variable t3s={t3}
if {t1}>0 then set t3s=minus {t3s}
\\Angle Theta3 = {t3s:2}\

lim off
lim res ratio from roll to ra0 or fld > 1
lim angle from {t3} to ra0 or fld > 20

page
RA /lim:att /graph:clean


print preview
report off
end