GHS Port Reference Center
Information for maritime designers, engineers and builders
Maintained by Creative Systems, Inc., Creators of GHS
Click here for information about GHS and other fine marine software.
Go to Main page

Demonstration of the BOOM Command
    `Demonstrates the BOOM command.
    `Also a good demonstration of command-level calculations.
    `Optional commands are preceded by the left apostrophe.
    
    PROJECT BOOMTEST
    
    READ FVW.GF
    
    REPORT
    
    \\\\\BOOM TEST\
    
    CRT(1)="FLOOD POINT #1" 0,12.27,12.5
    
    LIM AREA FROM EQU TO MAX > 15
    LIM AREA FROM EQU TO FLD > 15
    LIM AREA FROM EQU TO 40 > 15
    
    VCG 8
    HEEL=0
    DRAFT 8
    SOLVE WEIGHT, LCG
    
    MACRO BOOM
    BOOM"LOAD" 5, 18f, 0 ,16.7, %1,%2,%3  /NOWARN
    /
    
    MACRO RADIUS
    VARIABLE X
    SET X = %2 MINUS {HEEL}
    SET X = COS {X} TIMES %1
    \HOOKLOAD RADIUS = {X:2} {LUNIT}\
    /
    MACRO SKEW `param: swing angle
    `Unit vector normal to boom plane:
    `uB = uL * sin(swing) - uT * cos(swing)
    `Unit vector in direction of gravity:
    `uG = (uV * cos(heel) + uT * sin(heel)) * cos(trim) + uL * sin(trim)
    `uB * uG = sin(skew)
    VARIABLE b1,b2,g1,g2,t1,t2
    SET b1 = SIN %1
    SET b2 = COS %1
    SET b2 = MINUS {b2}
    SET t1 = COS {TRIM}
    SET g2 = SIN {HEEL}
    SET g2 = {g2} TIMES {t1}
    SET g1 = SIN {TRIM}
    SET t1 = {b1} TIMES {g1}
    SET t2 = {b2} TIMES {g2}
    SET t1 = {t1} PLUS {t2}
    SET t1 = {t1} TIMES 57.3
    SET t1 = ABS {t1}
    \SKEW ANGLE = {t1:1} DEGREES\
    /
    
    MACRO CASE
    PAGE
    \\\********** BOOM POSITION *********\
    \BOOM LENGTH = %1 FT.\
    \SWING ANGLE = %2 DEGREES (FROM STERN)\
    \TOPPING ANGLE = %3 DEGREES (FROM HORIZONTAL)\
    
    .BOOM %1,%2,%3
    `SOLVE MAXWGT:"LOAD"
    SOLVE
    .RADIUS %1, %3
    .SKEW %2
    STATUS `WEIGHT
    `RA /LIM
    /
    
    .CASE 30,90,30
    .CASE 30,90,60
    .CASE 30,45,20
    
    END
    

Add a free link to your site
Copyright © , Creative Systems, Inc.