GHS Port Reference Center
Information for maritime designers, engineers and builders
Maintained by Creative Systems, Inc., Creators of GHS
Click here for information about GHS and other fine marine software.
Go to Main page

Criterion for vessels of unusual proportion and form.
    ` "Criterion for vessels of unusual proportion and form" (CFR 46 170.173)
    
    proj 170173
    
    
    MACRO ParB
    LIMIT TITLE "170.173 Paragraph b"
    UNIT LT
    LIMIT (1) GM UPRIGHT > 0.49
    LIMIT (2) RA AT 30 OR MAX > 0.66
    LIMIT (3) ANGLE AT MAX > 25
    LIMIT (4) AREA FROM 0 TO 30 > 10.3
    LIMIT (5) AREA FROM 0 TO 40 OR FLD > 16.9
    LIMIT (6) AREA FROM 30 TO 40 OR FLD > 5.6
    /
    
    
    MACRO ParC
    LIMIT TITLE "170.173 Paragraph c"
    UNIT LT
    LIMIT (1) GM UPRIGHT > 0.49
    LIMIT (2) ANGLE AT MAX > 15
    LIMIT (3) AREA FROM 0 TO 40 OR FLD > 16.9
    LIMIT (4) AREA FROM 30 TO 40 OR FLD > 5.6
    LIMIT (5) AREA FROM 0 TO MAX AT 15 > 13.1
    LIMIT (6) AREA FROM 0 TO MAX AT 30 > 10.3
    /
    
    read sv.gf
    report
    
    UNIT MT
    crtpt "Engine Room Intake" 12.5f, 5.85, 9.5 /SYMM
    UNIT LT
    
    MACRO MaxVCG
    vcg=10 `floor
    maxvcg 10, 11, 12 /trim: -1, 0, 1
    /
    
    .ParB
    .MaxVCG
    
    LIMIT OFF
    .ParC
    .MaxVCG
    
    macro d
    `Checks limit margins at max VCG for given LCF draft and trim.
    heel=0
    trim=%2
    draft=%1
    solve weight, lcg
    vcg=max
    solve lcg
    vcg=max
    \\The following case is at trim = %2, displacement = {weight:2}\
    ra /lim /notab
    /
    macro t
    `Covers range of drafts as in MAXVCG at given trim.
    .d 10 %1
    .d 11 %1
    .d 12 %1
    /
    
    LIMIT(9) ANGLE FROM MAX TO 30 > 0
    maxvcg valid
    page
    \\Checking limit margins at maximum VCG as determined by Paragraph c\
    \>>> Check to make sure that limit #9 is positive for all cases <<<\
    \If so, Paragraph c applies.\
    
    `Trims as in MAXVCG:
    .t -1
    .t 0
    .t 1
    
    report off
    end
    
    

Add a free link to your site
Copyright © , Creative Systems, Inc.