PROJECT RA
READ FV180.GF
WE 150 0 0 8
SOLVE
ANGLES 0 -5 ... -180
REPORT
CRTPT(1) "LIFT1" 0, 11.465s, 2.218
CRTPT(2) "LIFT2" 0,  0.000 , 0.000
CRTPT(3) "LIFT3" 0, 11.465p, 2.218
RA
DI STATUS PROFILE, PLAN, BODY@0 /NOCRIT:ARROW /SYNC

SOLVE
PAGE 99%
STATUS
\SET UP GROUND WITH SLING AT REST\
GROUND "LIFT1" *, 0, 11.465s, 2.218 /PEN:0, 0.01
GROUND REPORT
STATUS GROUND
PAGE 99%

VARIABLE i=0, n=0
MACRO SAVE_REACT
 SET n={n} plus 1
 VARIABLE HE{n}={HEEL}, RE{n}={REACT}, h, f
 SET HE{n}=ABS {HEEL}
 IF %1=PRINT THEN set h={HE{n}}, f={RE{n}} | \               HEEL={ h:1};   SLING FORCE={ f:1}
/
SOLVE
.SAVE_REACT

\NOW LIFT THE SLING/GROUND POINT A FIXED AMOUNT\
\NOTE THE RESULTING HEEL ANGLE & SLING/GROUND REACTION
MACRO LIFT_GRND  `%1: GROUND POINT NUMBER (1, 2, OR 3);
 GROUND "LIFT%1" *,*,*,* /PEN:*+%2 /NOWARN    `INCREASING THE PENETRATION RAISES THE GROUND
` \PRE-SOLVE\
` STATUS
` GROUND REPORT
 SOLVE
` \POST-SOLVE\
` STATUS
` GROUND REPORT
 .SAVE_REACT PRINT
 WAIT .05
/
.LIFT_GRND(39) 1 .5
DELETE "LIFT1"

PAGE 99%
\SWITCH TO SLING POINT ON KEEL\
GROUND "LIFT2" *, 0,  0.000 , 0.000 /PEN:0, 0.01
.LIFT_GRND(9) 2 .5
DELETE "LIFT2"

PAGE 99%
\SWITCH TO SLING POINT ON PORT CHINE\
GROUND "LIFT3" *, 0, 11.465p, 2.218 /PEN:0, 0.01
.LIFT_GRND(20) 3 .5

MESSAGE PLOTSTART "SLING FORCE NEEDED TO ROLL VESSEL"
MESSAGE PLOTLABEL "PORT HEEL" "SLING REACTION"
MACRO PLOT_REACT
 SET i={i} plus 1
 IF {i}>{n} THEN EXIT
 ME {HE{i}}, {RE{i}}
 EXIT PLOT_REACT 
/
SET i=0 | .PLOT_REACT
MESSAGE PLOTEND

PRINT PREVIEW
REPORT OFF