clear

vari drft=5
vari inc=0.25
vari crt_list

vari (string) x1,x2,x3,x4,p1,p2,p3,p4,p5,p6,p7,p8,row,lbls,lind,stle
vari i,j,imax,jmax

macro drafts
 dr {drft}
 vcg 6
 so we lcg tcg
 di status profile, body@50f /sync
 \\ DRAFT = {depth} \ | \\
 sea /heading:180 /speed:9 /shw:crt /crt:{crt_list} /samp:10 /time:1
 set drft = {drft} plus {inc} 
/

macro rdln
 read p1,p2,p3,p4,p5,p6,p7,p8 /skip 
/

macro parseSHW
 .rdln 
 if {p3}={lind} then .rdln(3,1) `new page skip
 if {p1}="FREEBOARD" then set imax={i} | exit `end of table
 set i={i} plus 1
 vari shw{i}{j}, height{i}
 set shw{i}{j}={p8} | set height{i}={p4}
 exit parseSHW
/

macro parsePF
 read x1,x2,x3,x4 /skip
 if {x1}="DRAFT" then set j={j} plus 1 | vari draft_{j} | set draft_{j}={x3}
 if {x1}="SHIPPING" then if {x2}="WATER" then .rdln(2,1) | set i=0 | .parseSHW
 if eof then set jmax={j} | exit
 exit parsePF
/

macro columns
 set row="{row} {shw{i}{j}}"
 set i={i} plus 1
/

macro plot
 set row="{draft_{j}}", i=1
 .columns({imax},1)
 me {row}
 set j={j} plus 1
/

macro plot_labels
 set lbls="{lbls}, ""V={height{i}} m."""
 set i={i} plus 1
 set stle="{stle}, ""L"""
/

read tanker.gf

crt (1)  "bow DK+0.0" 97.573f,0,11.9 
crt (2)  "bow DK+0.5" 97.573f,0,12.4 
crt (3)  "bow DK+1.0" 97.573f,0,12.9 
crt (4)  "bow DK+1.5" 97.573f,0,13.4 
crt (5)  "bow DK+2.0" 97.573f,0,13.9 
crt (6)  "bow DK+2.5" 97.573f,0,14.4 
crt (7)  "bow DK+3.0" 97.573f,0,14.9 
crt (8)  "bow DK+3.5" 97.573f,0,15.4 
crt (9)  "bow DK+4.0" 97.573f,0,15.9 
crt (10) "bow DK+4.5" 97.573f,0,16.4 

set crt_list="1,2,3,4,5,6,7,8,9,10"
 
wave (spe) pm 30

report shw.pf
 .drafts(13)
report off

`--- Parse Report File ---
read (data) SHW.PF
read x1,x2,x3 /skip
set lind={x3} | set j=0 | .parsePF
read (data) off

`--- Create Custom Plot ---
report
me plotstart "Deck Submergence Frequency"
set lbls="""Draft (Ft) | Frequency"""
set i=1 | .plot_labels({imax},1)
me plotlabel {lbls}
me plotstyle {stle}
set j=1 | .plot({jmax},1)
me plotend
report off